산업 제조
산업용 사물 인터넷 | 산업자재 | 장비 유지 보수 및 수리 | 산업 프로그래밍 |
home  MfgRobots >> 산업 제조 >  >> Manufacturing Technology >> 제조공정

스마트 지하실 환기 시스템: 아두이노 기반 습도 제어

구성품 및 부품

부품 수량
Arduino Nano R3 1
IO Expander 1
IO Expander Bundle 1

앱 및 온라인 서비스

프로젝트 소개

기능 목록

환기 시스템 제작에 필요한 부품

배선도

(배선도 이미지 참조)

OLED 디스플레이

(디스플레이 표시 예시 이미지 참조)

왜 IO Expander를 사용하는가?

시스템 제작

  1. 아두이노 나노를 IO Expander에 연결하고 코드 프로그래밍 (6핀 헤더는 소프트웨어 시리얼 디버그 포트, 최종 설치 시 불필요)
  2. ONEWIRE_TO_I2C_ROM 주소를 본인 1-Wire to I2C 주소로 변경
  3. 110VAC 전선을 두 팬에 연결
  4. 인클로저에 PG7(7/16"), PG9(9/16") 구멍 뚫고 글랜드 장착 (PG7: 12V 입력, PG9: 센서/팬 선)
  5. 열려 있고 막히지 않은 벤트 하나를 배기구로 선정, 팬을 안쪽에 타이랩으로 고정 (바람이 밖으로 향하게)
  6. 반대쪽 벤트들은 흡기구로 개방, 인접 벤트들은 닫아 지역적 흐름이 아닌 전체 공간 순환 유도
  7. 기존 접근점으로 실외 습도 센서 선 끌어들이기 (집/장애물에서 충분히 떨어뜨려 주변 환경 정확 측정)
  8. 실외/실내 습도 센서를 키스톤 잭/인클로저에 배선 후 실내 장착 (실내 센서는 중앙이나 추가 습도 제어 필요한 구역)
  9. 50ft RJ11 와이어로 센서 연결, 팬 와이어와 함께 제어 인클로저 설치 위치로 배선
  10. 모든 부품 인클로저에 조립 (양면 테이프, 포장 폼으로 고정)
  11. 테스트: 아두이노를 IO Expander에서 분리해 PC에 직접 연결해 릴레이/팬 수동 제어 확인 후 최종 조립

업데이트: 2019.03.20

크롤스페이스에서 수개월 무고장 동작 중. 온수기 누수로 상대습도 95% 넘었으나 50% 미만으로 낮추는 데 성공. 지속 작동하는 제어 시스템임 입증!

SSD1306 0.96" OLED → SH1106 1.3" OLED로 교체 (더 크고 읽기 쉬움). 코드에서 'ST10'을 'ST13'으로만 변경하면 됨 (IO Expander 펌웨어 업데이트 덕분).

업데이트: 2019.09.12

v1.1 릴리스: 콜드 부트 시 OLED 화면이 공백으로 나오는 문제 수정. 여전히 크롤스페이스 환기 중!

코드

지하실/크롤스페이스 환기 시스템 (C/C++)

/* IO Expander
 * Basement/Crawlspace Ventilation System v1.1
 */

#include <math.h>
#include <SoftwareSerial.h>
#include <avr/wdt.h>
#include "IOExpander.h"

#define FAHRENHEIT
#define ONEWIRE_TO_I2C_ROM "i4s71"
#define INIT_OLED "st13;si;sc;sd"
#define HUMIDITY_SENSOR_INSIDE "s6t1"
#define HUMIDITY_SENSOR_OUTSIDE "s8t1"
#define FAN_ON "r1o"
#define FAN_OFF "r1f"
#define ABSOLUTE_DELTA_FAN_ON 1      // 실내 절대습도 - 실외 절대습도 >= 1 이면 팬 ON
#define ABSOLUTE_DELTA_FAN_OFF 0.5   // 실내 절대습도 - 실외 절대습도 <= 0.5 이면 팬 OFF
#define OUTSIDE_RELATIVE_FAN_ON 88   // 실외 상대습도 <= 88% 이면 팬 ON
#define OUTSIDE_RELATIVE_FAN_OFF 90  // 실외 상대습도 >= 90% 이면 팬 OFF
#define MINIMUM_TEMPERATURE 15       // 실외 온도 <= 15°C면 간헐 운전
#define FAN_ON_TIME (20*60*1000L)    // 20분
#define FAN_OFF_TIME (20*60*1000L)   // 20분

//#define SERIAL_DEBUG
#define SERIAL_TIMEOUT 5000

#ifdef SERIAL_DEBUG
SoftwareSerial swSerial(8,7);
#endif

struct HS {
  float temp;
  float relative;
  float absolute;
  bool error;
};

int led = 13;
bool init_oled = true;
long ontime, offtime;

#ifdef FAHRENHEIT
#define C2F(temp) CelsiusToFahrenheit(temp)
float CelsiusToFahrenheit(float celsius) {
  return ((celsius*9)/5)+32;
}
#else
#define C2F(temp) (temp)
#endif

void SerialPrint(const char* str, float decimal, char error) {
  Serial.print(str);
  if (error) Serial.print(F("NA"));
  else Serial.print(decimal, 1);
}

float DewPoint(float temp, float humidity) {
  float t = (17.625 * temp) / (243.04 + temp);
  float l = log(humidity/100);
  float b = l + t;
  return (243.04*b)/(17.625-b); // August-Roche-Magnus 근사
}

#define MOLAR_MASS_OF_WATER 18.01534
#define UNIVERSAL_GAS_CONSTANT 8.21447215

float AbsoluteHumidity(float temp, float relative) {
  // Buck (1981) 공식 사용: 6.1121 * exp(17.502*T/(T+240.97))
  // 정밀도: -30~35°C 범위에서 약 0.1°C
  return (6.1121 * pow(2.718281828, (17.67 * temp) / (temp + 243.5)) * relative * MOLAR_MASS_OF_WATER) / ((273.15 + temp) * UNIVERSAL_GAS_CONSTANT);
}

void ReadHumiditySensor(HS* hs) {
  SerialCmd("sr");
  if (SerialReadFloat(&hs->temp) && SerialReadFloat(&hs->relative)) {
    hs->absolute = AbsoluteHumidity(hs->temp, hs->relative);
    hs->error = false;
  } else hs->error = true;
  SerialReadUntilDone();
}

void setup() {
  Serial.begin(115200);
#ifdef SERIAL_DEBUG
  swSerial.begin(115200);
#endif
  pinMode(led, OUTPUT);
  wdt_enable(WDTO_8S); // 8초 워치독 타이머
  offtime = millis() - FAN_OFF_TIME;
}

void loop() {
  HS inside, outside;
  static bool fan = false;
  static bool cycle = false;
  static long last_time = -(60L * 1000L);

  Serial.println();
  if (SerialReadUntilDone()) {
    // 센서 읽기: 1분에 한 번만 (너무 자주 읽으면 자기 발열로 부정확)
    if (millis() - last_time > 60L * 1000L) {
      if (SerialCmdDone(HUMIDITY_SENSOR_INSIDE)) ReadHumiditySensor(&inside);
      if (SerialCmdDone(HUMIDITY_SENSOR_OUTSIDE)) ReadHumiditySensor(&outside);

      if (inside.error || outside.error) fan = false;
      else {
        if (fan) { // 팬 켜진 상태
          if (outside.relative >= OUTSIDE_RELATIVE_FAN_OFF || inside.absolute - outside.absolute <= ABSOLUTE_DELTA_FAN_OFF)
            cycle = fan = false;
          else {
            if (cycle && outside.temp <= MINIMUM_TEMPERATURE && millis() - ontime > FAN_ON_TIME)
              fan = false;
          }
          if (!fan) offtime = millis();
        } else { // 팬 꺼진 상태
          if (outside.relative <= OUTSIDE_RELATIVE_FAN_ON && inside.absolute - outside.absolute >= ABSOLUTE_DELTA_FAN_ON)
            cycle = fan = true;
          if (cycle && outside.temp <= MINIMUM_TEMPERATURE)
            fan = (millis() - offtime > FAN_OFF_TIME) ? true : false;
          if (fan) ontime = millis();
        }
      }

      if (fan) SerialCmdDone(FAN_ON);
      else SerialCmdDone(FAN_OFF);

      if (SerialCmdNoError(ONEWIRE_TO_I2C_ROM)) {
        if (init_oled) {
          SerialCmdDone(INIT_OLED);
          init_oled = false;
        }
        // OLED 표시 명령 구성 (실내/실외 온도, 습도, 절대습도, 팬 상태 등)
        SerialCmdDone("st13;sc;sf0;sa1;sd70,0,\"INSIDE\";sd127,0,\"OUTSIDE\";sf1;sa0;sd0,12,248,\"\""
#ifdef FAHRENHEIT
          "F"
#else
          "C"
#endif
          "\";sd0,30,\"%\";sf0;sd0,50,\"g/m\";sd20,46,\"3\";");
        SerialPrint("sf1;sa1;sd70,12,\"\"", C2F(inside.temp), inside.error);
        SerialPrint("\";sd70,30,\"\"", inside.relative, inside.error);
        SerialPrint("\";sd70,48,\"\"", inside.absolute, inside.error);
        SerialPrint("\";sd127,12,\"\"", C2F(outside.temp), outside.error);
        SerialPrint("\";sd127,30,\"\"", outside.relative, outside.error);
        SerialPrint("\";sd127,48,\"\"", outside.absolute, outside.error);
        Serial.print("\";");
        Serial.print("sf0;sa0;sd0,0,\"\"");
        if (fan) Serial.print("FAN");
        else Serial.print("v1.1");
        Serial.println("\";sd");
        SerialReadUntilDone();
      } else init_oled = true;

      last_time = millis();
    }
    delay(1000);
  } else {
    // 통신 오류 시 LED 깜빡임
    digitalWrite(led, HIGH); delay(500);
    digitalWrite(led, LOW); delay(500);
    init_oled = true;
  }
  wdt_reset(); // 워치독 리셋
}

회로도

아두이노 나노로 스마트 환기 시스템 구현 (회로도 이미지 참조)

제조공정

  1. 파이썬 연동 아두이노 RFID 출석 관리 시스템 구축하기
  2. 아두이노 우노 기반 인간 감지 로봇: 센서 통합 단계별 가이드
  3. 블루투스 제어 아두이노 스파이봇(Spybot) 만들기
  4. 플릭모트(FlickMote): 스마트 홈을 위한 제스처 제어 IR 리모컨
  5. DIY 아두이노 TV B-Gone: 모든 TV를 끄는 만능 리모컨
  6. 아두이노로 만드는 대형 LED 마스터 시계 (알람 기능 포함, 12m 거리에서도 식별 가능)
  7. SERENA: TFT LCD 터치스크린 탑재 아두이노 메가 2560 커스텀 알람 시스템
  8. 아두이노 자동 식물 급수 시스템 – 떠날 때도 안심하는 스마트 가드닝
  9. 실시간 산불 감시 시스템 - SMS 알림 기능 포함
  10. 환기 시스템 완벽 가이드: 실내 공기질을 지키는 자연·기계·고급 시스템