산업 제조
산업용 사물 인터넷 | 산업자재 | 장비 유지 보수 및 수리 | 산업 프로그래밍 |
home  MfgRobots >> 산업 제조 >  >> Manufacturing Technology >> 제조공정

ADXL345 가속도계로 아두이노 방향 추적하기: 단계별 가이드

개요

이 튜토리얼에서는 아두이노와 ADXL345 가속도계 센서를 사용하여 각도를 측정하고 방향을 추적하는 방법을 배웁니다. 더 자세한 내용은 아래 영상이나 작성된 튜토리얼을 참조하세요.

먼저 센서가 어떻게 작동하는지와 데이터를 읽는 방법을 설명하고, Processing 개발 환경을 사용하여 가속도계 방향의 3D 시각화를 만들겠습니다.

ADXL345 가속도계로 아두이노 방향 추적하기: 단계별 가이드

ADXL345 가속도계 작동 원리

먼저 ADXL345 센서가 어떻게 작동하는지 살펴보겠습니다. 이는 정적 및 동적 가속도 힘을 모두 측정할 수 있는 3축 가속도계입니다. 지구 중력은 전형적인 정적 힘의 예이며, 동적 힘은 진동, 움직임 등에 의해 발생할 수 있습니다.

ADXL345 가속도계로 아두이노 방향 추적하기: 단계별 가이드

가속도의 측정 단위는 미터/초²(m/s²)입니다. 하지만 가속도계 센서는 보통 측정값을 "g" 또는 중력 단위로 표현합니다. 1 "g"는 지구 중력 값으로 9.8 m/s²과 같습니다.

Z축이 위쪽을 향하여 중력과 반대 방향으로 평평하게 위치한 가속도계가 있다면, 센서의 Z축 출력은 1g가 됩니다. 반면 X와 Y 출력은 0이 됩니다. 중력이 이 축들에 수직이라 전혀 영향을 주지 않기 때문입니다.

ADXL345 가속도계로 아두이노 방향 추적하기: 단계별 가이드

센서를 뒤집으면 Z축 출력은 -1g가 됩니다. 이는 센서 출력이 중력에 대한 방향에 따라 -1g에서 +1g 사이에서 변할 수 있음을 의미합니다.

ADXL345 가속도계로 아두이노 방향 추적하기: 단계별 가이드

이 데이터와 약간의 삼각함수 수학을 사용하여 센서가 위치한 각도를 계산할 수 있습니다.

아두이노로 ADXL345 가속도계 데이터 읽기

아두이노를 사용하여 ADXL345 가속도계 데이터를 읽는 방법을 알아보겠습니다. 이 센서는 아두이노와 I2C 프로토콜로 통신하므로 전원용 두 선을 포함해 총 네 선만 필요합니다.

ADXL345 가속도계로 아두이노 방향 추적하기: 단계별 가이드

필요한 부품

  • ADXL345 가속도계 Amazon / Banggood / AliExpress
  • 아두이노 보드
  • 브레드보드와 점퍼 와이어

ADXL345 가속도계 아두이노 코드

ADXL345 가속도계 데이터를 읽는 아두이노 코드입니다.

/* 
   아두이노와 ADXL345 가속도계 튜토리얼
   by Dejan, https://howtomechatronics.com
*/
#include <Wire.h> // Wire 라이브러리 - I2C 통신용
int ADXL345 = 0x53; // ADXL345 센서 I2C 주소
float X_out, Y_out, Z_out; // 출력값

void setup() {
  Serial.begin(9600); // 시리얼 모니터 결과 출력을 위한 시리얼 통신 시작
  Wire.begin(); // Wire 라이브러리 초기화
  
  // ADXL345를 측정 모드로 설정
  Wire.beginTransmission(ADXL345); // 장치와 통신 시작
  Wire.write(0x2D); // POWER_CTL 레지스터(0x2D) 접근/통신
  // 측정 활성화
  Wire.write(8); // (8dec -> 0000 1000 binary) 비트 D3 하이로 측정 활성화
  Wire.endTransmission();
  delay(10);
}

void loop() {
  // === 가속도계 데이터 읽기 ===
  Wire.beginTransmission(ADXL345);
  Wire.write(0x32); // 레지스터 0x32(ACCEL_XOUT_H)부터 시작
  Wire.endTransmission(false);
  Wire.requestFrom(ADXL345, 6, true); // 총 6개 레지스터 읽기, 각 축 값은 2개 레지스터에 저장
  X_out = (Wire.read() | Wire.read() << 8); // X축 값
  X_out = X_out / 256; // +/- 2g 범위에서 데이터시트에 따라 원시 값을 256으로 나눔
  Y_out = (Wire.read() | Wire.read() << 8); // Y축 값
  Y_out = Y_out / 256;
  Z_out = (Wire.read() | Wire.read() << 8); // Z축 값
  Z_out = Z_out / 256;
  Serial.print("Xa= ");
  Serial.print(X_out);
  Serial.print(" Ya= ");
  Serial.print(Y_out);
  Serial.print(" Za= ");
  Serial.println(Z_out);
}

설명

먼저 I2C 통신용 Wire.h 라이브러리를 포함합니다. I2C 통신이 어떻게 작동하는지와 아두이노에서 사용하는 방법이 궁금하면 별도 상세 튜토리얼을 참조하세요.

I2C 통신을 사용하는 각 장치에는 고유한 I2C 주소가 있으며, 이 주소는 센서 데이터시트(ADXL345 데이터시트)에서 찾을 수 있습니다. 주소와 세 출력을 위한 변수를 정의한 후, setup 섹션에서 먼저 와이어 라이브러리를 초기화하고 가속도계를 측정 모드로 설정합니다. 데이터시트를 다시 보면 POWER_CTL 레지스터의 비트 D3를 하이(High)로 설정해야 함을 알 수 있습니다.

ADXL345 가속도계로 아두이노 방향 추적하기: 단계별 가이드

beginTransmission() 함수로 통신을 시작하고, write() 함수로 접근하려는 레지스터를 지정하고, 다시 write() 함수로 10진수 8을 써서 비트 D3를 하이로 설정합니다. 10진수 8은 이진수 0000 1000에 해당하며 비트 D3를 하이로 설정합니다.

// ADXL345를 측정 모드로 설정
Wire.beginTransmission(ADXL345);
Wire.write(0x2D); // POWER_CTL 레지스터 - 0x2D 접근
Wire.write(8); // 비트 D3 하이로 측정 활성화 (8dec -> 0000 1000 binary)
Wire.endTransmission();

loop 섹션에서 센서 데이터를 읽습니다. 각 축 데이터는 2바이트 또는 레지스터에 저장됩니다. 데이터시트에서 이 레지스터들의 주소를 볼 수 있습니다.

ADXL345 가속도계로 아두이노 방향 추적하기: 단계별 가이드

모두 읽기 위해 첫 번째 레지스터에서 시작하고, requestFrom() 함수로 6개 레지스터 읽기를 요청합니다. read() 함수로 각 레지스터에서 데이터를 읽고, 출력이 2의 보수 형태이므로 적절히 결합하여 올바른 값을 얻습니다.

// === 가속도계 데이터 읽기 ===
Wire.beginTransmission(ADXL345);
Wire.write(0x32); // 레지스터 0x32(ACCEL_XOUT_H)부터 시작
Wire.endTransmission(false);
Wire.requestFrom(ADXL345, 6, true); // 총 6개 레지스터 읽기
X_out = (Wire.read() | Wire.read() << 8); // X축 값
X_out = X_out / 256; // +/- 2g 범위에서 데이터시트에 따라 원시 값을 256으로 나눔
Y_out = (Wire.read() | Wire.read() << 8); // Y축 값
Y_out = Y_out / 256;
Z_out = (Wire.read() | Wire.read() << 8); // Z축 값
Z_out = Z_out / 256;

센서의 출력값은 선택된 감도에 따라 달라지며, +/- 2g에서 +/- 16g까지 다양합니다. 기본 감도는 +/- 2g이므로 -1에서 +1g 값을 얻기 위해 출력을 256으로 나눕니다. 256 LSB/g는 g당 256 카운트라는 뜻입니다.

ADXL345 가속도계로 아두이노 방향 추적하기: 단계별 가이드

응용 분야에 따라 적절한 감도를 선택할 수 있습니다. 방향 추적용으로는 +/- 2g 감도가 적당하지만, 갑작스러운 움직임, 충격 등에서 더 높은 가속도 힘을 감지해야 하는 응용 분야에서는 DATA_FORMAT 레지스터의 D1, D0 비트를 사용하여 다른 감도 범위를 선택할 수 있습니다.

ADXL345 가속도계로 아두이노 방향 추적하기: 단계별 가이드

ADXL345 가속도계 캘리브레이션

데이터를 읽은 후 시리얼 모니터에 출력하여 값이 예상대로인지 확인할 수 있습니다. 제 경우 값들이 정확히 나오지 않았으며, 특히 Z축에 0.1g의 눈에 띄는 오차가 있었습니다.

ADXL345 가속도계로 아두이노 방향 추적하기: 단계별 가이드

이 문제를 해결하려면 3개의 오프셋 캘리브레이션 레지스터를 사용하여 가속도계를 캘리브레이션해야 합니다. 방법은 다음과 같습니다. 센서를 평평하게 놓고 256으로 나누지 않은 원시(RAW) 값을 출력합니다.

ADXL345 가속도계로 아두이노 방향 추적하기: 단계별 가이드

이제 출력이 얼마나 벗어났는지 알 수 있습니다. 제 경우 Z 출력이 약 283이었습니다. 양수로 27 차이입니다. 이 값을 4로 나누면 Z축 오프셋 레지스터에 써야 할 숫자가 나옵니다. 코드를 업로드하면 Z축 출력이 정확히 256, 즉 1g가 됩니다.

// 이 코드는 SETUP 섹션에 들어갑니다
// 오프셋 캘리브레이션
// X축
Wire.beginTransmission(ADXL345);
Wire.write(0x1E); // X축 오프셋 레지스터
Wire.write(1);
Wire.endTransmission();
delay(10);
// Y축
Wire.beginTransmission(ADXL345);
Wire.write(0x1F); // Y축 오프셋 레지스터
Wire.write(-2);
Wire.endTransmission();
delay(10);
// Z축
Wire.beginTransmission(ADXL345);
Wire.write(0x20); // Z축 오프셋 레지스터
Wire.write(-7);
Wire.endTransmission();
delay(10);

필요하면 같은 방법으로 다른 축도 캘리브레이션하세요. 참고로 이 캘리브레이션은 레지스터에 영구적으로 기록되지 않습니다. 센서가 전원 켜질 때마다 이 값들을 레지스터에 써야 합니다.

캘리브레이션이 끝나면 이제 다음 두 공식으로 롤(Roll, X축 회전)과 피치(Pitch, Y축 회전)를 도(degree) 단위로 계산할 수 있습니다.

// 롤과 피치 계산 (X축 회전, Y축 회전)
roll = atan(Y_out / sqrt(pow(X_out, 2) + pow(Z_out, 2))) * 180 / PI;
pitch = atan(-1 * X_out / sqrt(pow(Y_out, 2) + pow(Z_out, 2))) * 180 / PI;

이 공식들이 어떻게 작동하는지 자세한 내용은 Freescale Semiconductor 애플리케이션 노트를 참조하세요.

아두이노와 ADXL345 가속도계 방향 추적 – 3D 시각화

이제 가속도계 3D 시각화 예제를 만들어 보겠습니다.

ADXL345 가속도계로 아두이노 방향 추적하기: 단계별 가이드

롤과 피치 값을 시리얼 포트로 보내는 같은 코드를 사용합니다. 전체 아두이노 코드:

/* 
   아두이노와 ADXL345 가속도계 - 3D 시각화 예제
   by Dejan, https://howtomechatronics.com
*/
#include <Wire.h>
int ADXL345 = 0x53;
float X_out, Y_out, Z_out;
float roll, pitch, rollF, pitchF = 0;

void setup() {
  Serial.begin(9600);
  Wire.begin();
  
  // ADXL345 측정 모드 설정
  Wire.beginTransmission(ADXL345);
  Wire.write(0x2D);
  Wire.write(8); // 비트 D3 하이로 측정 활성화
  Wire.endTransmission();
  delay(10);
  
  // 오프셋 캘리브레이션
  // X축
  Wire.beginTransmission(ADXL345);
  Wire.write(0x1E);
  Wire.write(1);
  Wire.endTransmission();
  delay(10);
  // Y축
  Wire.beginTransmission(ADXL345);
  Wire.write(0x1F);
  Wire.write(-2);
  Wire.endTransmission();
  delay(10);
  // Z축
  Wire.beginTransmission(ADXL345);
  Wire.write(0x20);
  Wire.write(-9);
  Wire.endTransmission();
  delay(10);
}

void loop() {
  // === 가속도계 데이터 읽기 ===
  Wire.beginTransmission(ADXL345);
  Wire.write(0x32);
  Wire.endTransmission(false);
  Wire.requestFrom(ADXL345, 6, true);
  X_out = (Wire.read() | Wire.read() << 8);
  X_out = X_out / 256;
  Y_out = (Wire.read() | Wire.read() << 8);
  Y_out = Y_out / 256;
  Z_out = (Wire.read() | Wire.read() << 8);
  Z_out = Z_out / 256;
  
  // 롤과 피치 계산
  roll = atan(Y_out / sqrt(pow(X_out, 2) + pow(Z_out, 2))) * 180 / PI;
  pitch = atan(-1 * X_out / sqrt(pow(Y_out, 2) + pow(Z_out, 2))) * 180 / PI;
  
  // 로우패스 필터
  rollF = 0.94 * rollF + 0.06 * roll;
  pitchF = 0.94 * pitchF + 0.06 * pitch;
  
  Serial.print(rollF);
  Serial.print("/");
  Serial.println(pitchF);
}

Processing 개발 환경에서 이 값들을 수신하여 만들 3D 객체를 회전시키는 데 사용합니다. 전체 Processing 코드:

/* 
   아두이노와 ADXL345 가속도계 - 3D 시각화 예제
   by Dejan, https://howtomechatronics.com
*/
import processing.serial.*;
import java.awt.event.KeyEvent;
import java.io.IOException;

Serial myPort;
String data = "";
float roll, pitch;

void setup() {
  size(960, 640, P3D);
  myPort = new Serial(this, "COM8", 9600); // 시리얼 통신 시작
  myPort.bufferUntil('\n');
}

void draw() {
  translate(width/2, height/2, 0);
  background(33);
  textSize(22);
  text("Roll: " + int(roll) + " Pitch: " + int(pitch), -100, 265);
  
  // 객체 회전
  rotateX(radians(roll));
  rotateZ(radians(-pitch));
  
  // 3D 객체
  textSize(30);
  fill(0, 76, 153);
  box(386, 40, 200); // 박스 그리기
  textSize(25);
  fill(255, 255, 255);
  text("www.HowToMechatronics.com", -183, 10, 101);
}

// 시리얼 포트에서 데이터 읽기
void serialEvent(Serial myPort) {
  // 시리얼 포트에서 '\n' 문자까지 데이터를 읽어 문자열 변수 "data"에 저장
  data = myPort.readStringUntil('\n');
  // 라인피드 외 바이트를 받은 경우:
  if (data != null) {
    data = trim(data);
    // "/"에서 문자열 분할
    String[] items = split(data, '/');
    if (items.length > 1) {
      //--- 롤, 피치 (도 단위)
      roll = float(items[0]);
      pitch = float(items[1]);
    }
  }
}

설명

시리얼 라이브러리를 포함하고, 시리얼 포트와 업로드된 아두이노 스케치와 일치해야 하는 보드레이트를 정의합니다. 들어오는 데이터를 읽어 적절한 롤과 피치 변수에 저장합니다. 메인 draw 루프에서 이 값들을 사용하여 3D 객체를 회전시키며, 이 경우 특정 색상과 텍스트가 있는 간단한 박스입니다.

스케치를 실행하면 3D 객체가 나타나 가속도계 센서의 방향을 추적합니다. 객체가 약간 흔들리는데, 가속도계가 중력뿐만 아니라 손 움직임으로 인한 작은 힘도 포착하기 때문입니다. 더 부드러운 결과를 위해 간단한 로우패스 필터를 사용할 수 있습니다. 아두이노 코드에 이전 상태의 94%와 현재 상태 또는 각도의 6%를 더하는 필터를 구현했습니다.

// 로우패스 필터
rollF = 0.94 * rollF + 0.06 * roll;
pitchF = 0.94 * pitchF + 0.06 * pitch;

이 필터로 객체가 훨씬 부드럽게 움직이지만, 반응 속도가 느려지는 부작용도 있습니다. 또한 Yaw( Z축 회전)가 빠져 있음을 알 수 있습니다. 3축 가속도계 데이터만으로는 Yaw를 계산할 수 없습니다.

이를 수행하고 방향 추적 센서의 전반적인 성능을 개선하려면 자이로스코프라는 추가 센서를 포함하고 그 데이터를 가속도계와 융합해야 합니다.

ADXL345 가속도계로 아두이노 방향 추적하기: 단계별 가이드

ADXL345 가속도계를 자이로스코프 센서와 조합하거나, 단일 칩에 3축 가속도계와 3축 자이로스코프가 통합된 MPU6050 IMU를 사용할 수 있습니다. 이 센서에 대한 더 자세한 튜토리얼은 다음 영상에서 확인하세요.

이 튜토리얼이 도움이 되었기를 바랍니다. 궁금한 점은 아래 댓글 섹션에 자유롭게 질문해 주시고, 아두이노 프로젝트 모음도 확인해 보세요.

제조공정

  1. 아두이노 & MPU6050: SG90 & MG996R 서보 모터 정밀 제어
  2. u-blox LEA-6H GPS 모듈: 아두이노 & 파이썬 연동 가이드
  3. DHT11 온습도 센서와 블링크(Blynk)로 원격 모니터링하기 - 아두이노 단계별 튜토리얼
  4. 아두이노 Due에서 음성 인식 및 합성 마스터하기
  5. 아두이노로 음악 톤 만들기: 88키 피아노 음계 구현 가이드
  6. 아두이노를 NMEA-0183에 연결하기: 단계별 가이드
  7. 아두이노로 Modbus 마스터하기: 단계별 완벽 가이드
  8. 아두이노 나노 기반 블루투스 스마트 커피 메이커 - 온도 모니터링 및 자동 추출
  9. 아두이노와 알렉사로 제어하는 애니메이션 스마트 LED 스트립 만들기
  10. 음성 제어 LED 프로젝트: 아두이노 마이크로 + BitVoicer 서버로 음성 인식